Aminet 3/Aminet 3 - July 1994.iso/Aminet/util/rexx/InfraRexx1_0.lha/InfraRexx/Install

Text File | 1994-04-25 | 6.9 KB | 349 lines

(message
  "\nWelcome to the\nInfraRexx Installer Utility\n\n"
  "This program will conveniently install\n"
  "InfraRexx on your Amiga computer system.\n\n"
  "Please read the AmigaGuide for\n"
  "more information about InfraRexx.\n\n"
  "InfraRexx © 1994 Leon Woestenberg\n"
)
(welcome)

(transcript "Installing InfraRexx 1.0...")
;
; check AmigaOS version
;
(if
  (<
    (/
      (getversion)
      65536
    )
    37
  )
  (abort "\nInfraRexx requires at least AmigaOS Release 2.04 to run.\n\n"
         "Press the Proceed button to abort the installation procedure."
  )
)
(complete 0)

;
; Ask where to install the InfraRexx drawer
;
(set infrarexx-dest
  (tackon
    (askdir
      (prompt "Where should the InfraRexx drawer be installed?")
      (help @askdir-help)
      (default @default-dest)
    )
    "InfraRexx"
  )
)
(makedir infrarexx-dest (infos))
(set @default-dest infrarexx-dest)

(complete 20)

(copyfiles
  (source "InfraRexxEditor")
  (dest infrarexx-dest)
  (infos)
)
(copyfiles
  (source "InfraRexxDaemon")
  (dest infrarexx-dest)
  (infos)
)

(complete 40)

(if
  (askbool
    (prompt "\nDo you want to install the dutch language catalogs?")
    (help @askbool-help)
  )
  (
    (if
      (exists "LOCALE:Catalogs/nederlands/InfraRexx/")
      (
        (transcript "InfraRexx catalog drawer already existed.")
      )
      (
        (makedir "LOCALE:Catalogs/nederlands/InfraRexx")
      )
    )
    (foreach "Catalogs/nederlands/InfraRexx/" "#?.catalog"
      (copyfiles
        (prompt "Installing the dutch language catalogs...")
        (source
          (tackon "Catalogs/nederlands/InfraRexx/" @each-name)
        )
        (dest "LOCALE:Catalogs/nederlands/InfraRexx/")
        (help @copyfiles-help)
      )
    )
  )
)

(complete 60)

(if
  (askbool
    (prompt "\nDo you want to install the english AmigaGuide manual?")
    (help "The AmigaGuide manual describes how to use InfraRexx, "
          "copyrights and disclaimers, background information and "
          "developer information.\n\n"
    @askbool-help)
  )
  (
    (copyfiles
      (prompt "Installing the english AmigaGuide manual...")
      (source "InfraRexx.guide")
      (dest
        (set guide-dest
          (askdir
            (prompt "Please select a place for the english AmigaGuide manual.")
            (default infrarexx-dest)
            (help @askdir-help)
          )
        )
      )
      (infos)
      (help @copyfiles-help)
    )
    (if
      (>
        (exists
          "SYS:Utilities/MultiView"
          (noreq)
        )
        0
      )
      (
        (tooltype
          (dest
            (tackon guide-dest "InfraRexx.guide")
          )
          (setdefaulttool "MultiView")
        )
      )
    )
  )
)

(complete 70)

(set codesets-used
  (askchoice
    (prompt "Please select the command codeset that you want to use initially:\n")
    (choices "Panasonic"
             "Philips"
             "Sony"
    )
    (default 0)
    (help "You are asked for a command codeset that will be used if you start "
          "the InfraRexx Daemon immediately after installation. Of course you "
          "can change this later via the tooltype or CLI arguments.\n\n"
          @askchoice-help
    )
  )
)
(tooltype
  (dest
    (tackon
      infrarexx-dest
      "InfraRexxDaemon"
    )
  )
  (settooltype
    "FROM"
    (tackon
      infrarexx-dest
      (select codesets-used
        "Codesets/Panasonic"
        "Codesets/Philips"
        "Codesets/Sony"
      )
    )
  )
  (noposition)
)
(set
  codesets-additional
  (BITOR
    codesets-additional
    (select codesets-used
      256
      512
      2048
    )
  )
)
(set codesets-additional
  (askoptions
    (prompt "Please select additional command codesets that you want to install: (Empty codesets are marked with ¹)\n"
    (choices "Akai¹"
             "Canon¹"
             "Goldstar¹"
             "Hitachi¹"
             "JVC¹"
             "Kenwood¹"
             "NEC¹"
             "Onkyo¹"
             "Panasonic"
             "Philips"
             "Pioneer¹"
             "Sony"
             "Teac¹"
             "Technics¹"
             "Yamaha¹"
    )
    (default codesets-additional)
    (help @askoptions-help)
    )
  )
)
(complete 75)
(set
  codesets-additional
  (BITOR
    codesets-additional
    (select codesets-used
      256
      512
      2048
    )
  )
)

(set current 0)
(while
  (> codesets-additional 0)
  (
    (if
      (BITAND codesets-additional (shiftleft 1 current))
      (
        (copyfiles
          (prompt "Copying the selected codesets...\n")
          (source
            (tackon
              "Codesets"
              (select current
                      "Akai"
                      "Canon"
                      "Goldstar"
                      "Hitachi"
                      "JVC"
                      "Kenwood"
                      "NEC"
                      "Onkyo"
                      "Panasonic"
                      "Philips"
                      "Pioneer"
                      "Sony"
                      "Teac"
                      "Technics"
                      "Yamaha"
              )
            )
          )
          (dest
            (tackon infrarexx-dest "Codesets")
          )
          (help @copyfiles-help)
        )
        (set
          codesets-additional
          (-
            codesets-additional
            (shiftleft 1 current)
          )
        )
      )
    )
    (set current (+ current 1))
    (complete
      (+
        75
        current
      )
    )
  )
)
(complete 90)

(if
  (askbool
    (prompt "\nDo you want to install the examples?\n")
    (help "The examples show the use of the ARexx interface, via several "
          "Amiga programs.\n\n"
          @askbool-help
    )
  )
  (
    (makedir
      (tackon infrarexx-dest "Examples")
    )
    (copyfiles
      (prompt "Installing the examples...")
      (source "Examples")
      (all)
      (infos)
      (dest
        (tackon infrarexx-dest "Examples")
      )
      (help @copyfiles-help)
    )
  )
)
(complete 95)
(if
  (askbool
    (prompt "\nDo you want to install the hardware design?\n")
    (help "The hardware designs describe how to build the hardware "
          "that is required by InfraRexx to transmit and send infrared "
          "signals.\n\n"
          @askbool-help
    )
  )
  (
    (makedir
      (tackon infrarexx-dest "Hardware")
    )
    (copyfiles
      (prompt "Installing the hardware design...")
      (source "Hardware")
      (all)
      (infos)
      (dest
        (tackon infrarexx-dest "Hardware")
      )
      (help @copyfiles-help)
    )
    (if
      (>
        (exists
          "SYS:Utilities/MultiView"
          (noreq)
        )
        0
      )
      (
        (tooltype
          (dest
            (tackon infrarexx-dest "Hardware/InfraJoy.iff")
          )
          (setdefaulttool "MultiView")
        )
      )
    )
  )
)
(complete 100)


(exit "You have just installed release 1.0 of InfraRexx.\n\n"
      "Have fun with it!\n\n"
      "InfraRexx © 1994 Leon Woestenberg"
)